[R3dKap]

Salut @Mickael,

Il faut que tu fasses les modifs dans ton fichier Excel pour que le convertisseur les prenne en compte.

Pour faire rentrer toutes tes colonnes dans une seule page, dans Excel tu dois passer en affichage Aperçu des sauts de page en cliquant sur cet icône tout en bas à droite de ta fenêtre Excel :

Tu verras alors les sauts de pages de ta feuille :

Ensuite, tu dois glisser la barre verticale en pointillés vers la droite jusqu’à ta dernière colonne pour obtenir ceci au final :

Enfin, il faut mettre ta feuille au format paysage via la barre d’outil Excel :

Enregistre alors ton fichier Excel. La conversion prendra en compte tous ces éléments dans le PDF final (je l’ai testé chez moi).

😉

[Mickael]

Le souci c’est que j’ai une centaine de tableaux ou il faut faire ces réglages. Je souhaterais automatiser ces réglages. Est t’il possible de changer les réglages par défault d’excel en mode paysage et ajuster à une page sans devoir le faire pour 100 tableaux et si possible sans utiliser de macros.

• Cette réponse a été modifiée Il y a 2 mois, 3 semaines par  Mickael.

[R3dKap]

100 tableaux dans un seul fichier ou 100 fichiers avec 1 tableau ?

[Guy]

Bonjour,

Si tous les classeurs sont dans un même dossier, une solution serait de passer par VBA. Oui, je sais, on est sur un forum Power Automate. Mais ça pourrait vous simplifier la vie.

Voici un code qui parcoure tous les classeurs dans un dossier, chaque feuille du classeur et qui les ajuste au format paysage en incluant toutes les colonnes.

Sub FormaterTableaux()
Dim wb As Workbook
Dim ws As Worksheet
Dim chemin As String
Dim fichier As String

‘ Définir le chemin du dossier contenant les classeurs
chemin = “C:\Chemin\Vers\Vos\Classeurs\”

‘ Désactiver les alertes et les mises à jour de l’écran pour accélérer le processus
Application.ScreenUpdating = False
Application.DisplayAlerts = False

‘ Parcourir tous les fichiers dans le dossier
fichier = Dir(chemin & “*.xlsx”)
Do While fichier <> “”
‘ Ouvrir chaque classeur
Set wb = Workbooks.Open(chemin & fichier)

‘ Parcourir chaque feuille de calcul dans le classeur
For Each ws In wb.Worksheets
‘ Définir le format paysage
ws.PageSetup.Orientation = xlLandscape

‘ Ajuster les colonnes pour qu’elles tiennent sur une page
ws.PageSetup.FitToPagesWide = 1
ws.PageSetup.FitToPagesTall = False

‘ Ajuster les marges pour maximiser l’espace disponible
ws.PageSetup.LeftMargin = Application.InchesToPoints(0.5)
ws.PageSetup.RightMargin = Application.InchesToPoints(0.5)
ws.PageSetup.TopMargin = Application.InchesToPoints(0.5)
ws.PageSetup.BottomMargin = Application.InchesToPoints(0.5)
Next ws

‘ Enregistrer et fermer le classeur
wb.Close SaveChanges:=True

‘ Passer au fichier suivant
fichier = Dir
Loop

‘ Réactiver les alertes et les mises à jour de l’écran
Application.ScreenUpdating = True
Application.DisplayAlerts = True
End Sub

En espérant que cette solution puisse convenir.

Cordialement.